Usando o MPU6050 com o ESP32
Usando o MPU6050 com o ESP32
Este guia explica como conectar e usar um acelerômetro e giroscópio MPU6050 com um microcontrolador ESP32. O código fornecido utiliza a biblioteca
Adafruit_MPU6050para inicializar o sensor, definir as faixas do acelerômetro e do giroscópio, configurar a largura de banda do filtro e ler os dados de aceleração, rotação e temperatura. Esses dados são então impressos no monitor serial.
Introdução
Usar o MPU 6050 com um ESP32 envolve o controle de pinos GPIO (General Purpose Input/Output). Aqui está um passo a passo de como fazer isso!
Requisitos
- Hardware
- ESP32 - O ESP32 é uma série de microcontroladores de baixo custo e baixo consumo de energia. É também um sistema em um único chip com microcontrolador, Wi-Fi e Bluetooth integrados.
- MPU 6050 - Acelerômetro e giroscópio
- Resistores - Usados para limitar a corrente através do pino de dados do Sensor DHT22.
- Software
- Arduino IDE ou Wokwi para programar/simular o código a ser executado no ESP32.
- Certifique-se de instalar o driver do ESP32 para conseguir enviar o código para o ESP32.
Conexões de Hardware
Exemplo de Código 1 - Usando a Adafruit MPU6050
// Basic demo for accelerometer readings from Adafruit MPU6050
#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <Wire.h>
Adafruit_MPU6050 mpu;
void setup(void) {
Serial.begin(115200);
while (!Serial)
delay(10); // will pause Zero, Leonardo, etc until serial console opens
Serial.println("Adafruit MPU6050 test!");
// Try to initialize!
if (!mpu.begin()) {
Serial.println("Failed to find MPU6050 chip");
while (1) {
delay(10);
}
}
Serial.println("MPU6050 Found!");
mpu.setAccelerometerRange(MPU6050_RANGE_8_G);
Serial.print("Accelerometer range set to: ");
switch (mpu.getAccelerometerRange()) {
case MPU6050_RANGE_2_G:
Serial.println("+-2G");
break;
case MPU6050_RANGE_4_G:
Serial.println("+-4G");
break;
case MPU6050_RANGE_8_G:
Serial.println("+-8G");
break;
case MPU6050_RANGE_16_G:
Serial.println("+-16G");
break;
}
mpu.setGyroRange(MPU6050_RANGE_500_DEG);
Serial.print("Gyro range set to: ");
switch (mpu.getGyroRange()) {
case MPU6050_RANGE_250_DEG:
Serial.println("+- 250 deg/s");
break;
case MPU6050_RANGE_500_DEG:
Serial.println("+- 500 deg/s");
break;
case MPU6050_RANGE_1000_DEG:
Serial.println("+- 1000 deg/s");
break;
case MPU6050_RANGE_2000_DEG:
Serial.println("+- 2000 deg/s");
break;
}
mpu.setFilterBandwidth(MPU6050_BAND_21_HZ);
Serial.print("Filter bandwidth set to: ");
switch (mpu.getFilterBandwidth()) {
case MPU6050_BAND_260_HZ:
Serial.println("260 Hz");
break;
case MPU6050_BAND_184_HZ:
Serial.println("184 Hz");
break;
case MPU6050_BAND_94_HZ:
Serial.println("94 Hz");
break;
case MPU6050_BAND_44_HZ:
Serial.println("44 Hz");
break;
case MPU6050_BAND_21_HZ:
Serial.println("21 Hz");
break;
case MPU6050_BAND_10_HZ:
Serial.println("10 Hz");
break;
case MPU6050_BAND_5_HZ:
Serial.println("5 Hz");
break;
}
Serial.println("");
delay(100);
}
void loop() {
/* Get new sensor events with the readings */
sensors_event_t a, g, temp;
mpu.getEvent(&a, &g, &temp);
/* Print out the values */
Serial.print("Acceleration X: ");
Serial.print(a.acceleration.x);
Serial.print(", Y: ");
Serial.print(a.acceleration.y);
Serial.print(", Z: ");
Serial.print(a.acceleration.z);
Serial.println(" m/s^2");
Serial.print("Rotation X: ");
Serial.print(g.gyro.x);
Serial.print(", Y: ");
Serial.print(g.gyro.y);
Serial.print(", Z: ");
Serial.print(g.gyro.z);
Serial.println(" rad/s");
Serial.print("Temperature: ");
Serial.print(temp.temperature);
Serial.println(" degC");
Serial.println("");
delay(500);
}Explicação
Este código demonstra como ler dados de acelerômetro, giroscópio e temperatura de um sensor Adafruit MPU6050 usando a biblioteca Adafruit_MPU6050. Vamos analisar o código seção por seção:
Adafruit_MPU6050.h: Este arquivo de cabeçalho contém as definições e funções necessárias para interagir com o sensor MPU6050.Adafruit_Sensor.h: Este cabeçalho fornece uma interface comum para trabalhar com vários sensores da Adafruit.Wire.h: Este cabeçalho habilita a comunicação I2C, que é usada para se comunicar com o MPU6050.Adafruit_MPU6050 mpu;- Cria o objeto MPU usando a biblioteca MPU.Serial.begin(115200): Inicializa a comunicação serial com uma taxa de transmissão (baud rate) de 115200. Isso é usado para imprimir os dados do sensor no monitor serial.mpu.begin(): Inicializa o sensor MPU6050. Se a inicialização falhar, ele imprime uma mensagem de erro e interrompe o programa.mpu.setAccelerometerRange(…): Define a faixa de medição do acelerômetro. O exemplo usaMPU6050_RANGE_8_G, o que significa que ele pode medir acelerações de até ±8g. Outras opções são ±2g, ±4g e ±16g. O código então imprime a faixa selecionada.mpu.setGyroRange(…): Define a faixa de medição do giroscópio. O exemplo usaMPU6050_RANGE_500_DEG, o que significa que ele pode medir velocidades angulares de até ±500°/s. Outras opções são ±250°/s, ±1000°/s e ±2000°/s. O código então imprime a faixa selecionada.mpu.setFilterBandwidth(…): Define a largura de banda do filtro para as leituras do sensor. Uma largura de banda menor reduz o ruído, mas também diminui o tempo de resposta. O exemplo usaMPU6050_BAND_21_HZ. O código então imprime a largura de banda selecionada.sensors_event_t a, g, temp;: Cria três variáveis do tiposensors_event_tpara armazenar os dados do acelerômetro, giroscópio e temperatura, respectivamente.mpu.getEvent(&a, &g, &temp);: Lê os dados do sensor e os armazena nas variáveisa,getemp.Serial.print(…): Imprime as leituras do sensor no monitor serial. A aceleração é impressa em m/s², a rotação em rad/s e a temperatura em °C.delay(500): Pausa o programa por 500 milissegundos (0,5 segundos) antes de fazer a próxima leitura.